@ECHO OFF

:: FILE: DelCook.bat
::
:: Deletes Cookies (even read-only ones)
::
:: I tried to find every cookies folder or file with all
:: the different Internet Explorer & Windows versions.
::
:: AUTHOR: Parcifal Aertssen
:: http://www.aqtronix.com

ECHO.
ECHO Removing Cookies please wait...
ECHO _____________________________________________________________

IF "%OS%"=="Windows_NT" GOTO Windows_NT

:: ***************************************************************
:: *                                                             *
:: *                      Windows 95,98,ME stuff                 *
:: *                                                             *
:: ***************************************************************


:: Internet Explorer 2.0
DEL "C:\Program Files\Plus!\Microsoft Internet\cookies.txt"

:: Internet Explorer 3.0 for Windows for Workgroups and Windows NT version 3.51: Internet Explorer installation directory as the file name Emcookie.dat. 

:: Internet Explorer 3.0 & 4.x & 5.0 for Windows 95, Internet Explorer 4.x & 5.0 for Windows 98
DEL "%windir%\Cookies\*.txt"

:: if User Profiles are enabled on Windows 95 of 98
DEL "%windir%\profiles\%USERNAME%\cookies\*.txt"

GOTO End



:Windows_NT
:: ***************************************************************
:: *                                                             *
:: *                    windows NT,2000,XP stuff                 *
:: *                                                             *
:: ***************************************************************

:: Internet Explorer 1.5 for Windows NT
DEL /q /f "%systemroot%\cookie.jar"

:: Internet Explorer 2.0
DEL /q /f "C:\Program Files\Plus!\Microsoft Internet\cookies.txt"

:: Internet Explorer 3.0 for Windows NT
DEL /q /f "%systemroot%\COOKIES\*.txt"

:: Internet Explorer 3.0 for Windows for Workgroups and Windows NT version 3.51: Internet Explorer installation directory as the file name Emcookie.dat. 

:: Internet Explorer 4.x & 5.0 for Windows NT
DEL /q /f "%systemroot%\profiles\%username%\Cookies\*.txt"

:: Internet Explorer for Windows 2000
DEL /q /f "%USERPROFILE%\Cookies\*.txt"

GOTO End


:End
ECHO _____________________________________________________________
ECHO Done removing cookies.
ECHO.